Sports Illustrated for Kids - Awesome Athletes!/Sports Illustrated for Kids - Awesome Athletes!.iso/iv.dir/00005_Monitor List Scripts.ls

Text File | 1996-04-19 | 5.0 KB | 195 lines

on IncrementMonitorList monitor
  global givState
  MessagePut("increment monitor" && monitor)
  PlaySoundWait("CLIK1.AIF")
  if count(the questionSelectList of givState) > 0 then
    set the questionSelectList of givState to []
    DisplayFromList()
  end if
  set lis to GetMonitorListByNumber(monitor)
  if count(lis) = 0 then
    exit
  end if
  set tmp to GetMonitorPtr(givState, monitor)
  set tmp to tmp + 1
  if tmp > count(lis) then
    set tmp to 1
  end if
  SetMonitorPtr(givState, monitor, tmp)
  SetActiveMonitor(monitor)
  MessagePut("current clip:" && GetClipID(monitor))
  DisplayMonitor(monitor)
  if monitor = 1 then
    SetAthleteFromMonitor(givState)
  end if
  SetQuestionTextBoxHilite(tmp)
end

on DecrementMonitorList monitor
  global givState
  MessagePut("decrement monitor" && monitor)
  PlaySoundWait("CLIK1.AIF")
  if count(the questionSelectList of givState) > 0 then
    set the questionSelectList of givState to []
    DisplayFromList()
  end if
  set lis to GetMonitorListByNumber(monitor)
  if count(lis) = 0 then
    exit
  end if
  set tmp to GetMonitorPtr(givState, monitor)
  set tmp to tmp - 1
  if tmp < 1 then
    set tmp to count(lis)
  end if
  MessagePut("setting ptr to count(lis), =" && tmp)
  SetMonitorPtr(givState, monitor, tmp)
  SetActiveMonitor(monitor)
  MessagePut("current clip:" && GetClipID(monitor))
  DisplayMonitor(monitor)
  if monitor = 1 then
    SetAthleteFromMonitor(givState)
  end if
  SetQuestionTextBoxHilite()
end

on SetActiveMonitor monitor, override, init
  global givState
  if (monitor = the activeMonitor of givState) and voidp(override) then
    MessagePut("SetActiveMonitor ignored, same value for monitor")
    nothing()
  else
    MessagePut("setting active monitor:" && monitor)
    set the activeMonitor of givState to monitor
    if voidp(init) then
      set the questionSelectList of givState to []
    end if
    SetMonitorIndicators(monitor)
    SetQuestionTextBox(1)
  end if
end

on DisplayMonitor mon
  global givState, givBASEMONITORSPRITE
  MessagePut("display monitor" && mon & "...")
  set clip to GetClipID(mon)
  if clip = "none" then
    set the castNum of sprite (givBASEMONITORSPRITE + mon) to the number of cast "colorbar.BMP"
  else
    set the castNum of sprite (givBASEMONITORSPRITE + mon) to the number of cast (clip & ".BMP")
  end if
  updateStage()
end

on MonitorDialDrag
  global givState
  set H to 0
  set H to the mouseH
  PlaySoundWait("SCHWAK.AIF")
  set executeOnce to 1
  set mon to 0
  if count(GetMonitorListByNumber(6)) > 0 then
    set mon6Active to 1
  else
    set mon6Active to 0
  end if
  if count(the editList of givState) > 0 then
    set mon3Active to 1
  else
    set mon3Active to 0
  end if
  if the mode of givState = #edit then
    repeat while the mouseDown or executeOnce
      if executeOnce then
        set executeOnce to 0
      else
        set H to the mouseH
      end if
      if H < 66 then
        SetMonitorIndicators(1)
        set mon to 1
        next repeat
      end if
      if H < 86 then
        SetMonitorIndicators(2)
        set mon to 2
        next repeat
      end if
      if H < 106 then
        SetMonitorIndicators(3)
        set mon to 3
        next repeat
      end if
      if (H < 136) and mon6Active then
        SetMonitorIndicators(6)
        set mon to 6
        next repeat
      end if
      if H < 153 then
        SetMonitorIndicators(4)
        set mon to 4
        next repeat
      end if
      SetMonitorIndicators(5)
      set mon to 5
    end repeat
  else
    repeat while the mouseDown or executeOnce
      if executeOnce then
        set executeOnce to 0
      else
        set H to the mouseH
      end if
      if H < 86 then
        SetMonitorIndicators(1)
        set mon to 1
        next repeat
      end if
      if H < 106 then
        if mon3Active then
          SetMonitorIndicators(3)
          set mon to 3
        else
          SetMonitorIndicators(1)
          set mon to 1
        end if
        next repeat
      end if
      if (H < 136) and mon6Active then
        SetMonitorIndicators(6)
        set mon to 6
        next repeat
      end if
      SetMonitorIndicators(4)
      set mon to 4
    end repeat
  end if
  SetActiveMonitor(mon)
end

on SetMonitorIndicators monitor
  global givDebug, givMONITORDIALSPRITE, givMONITORINDICATORSPRITE, givState
  set monitorIndicatorH to [74, 74, 74, 401, 568, 238]
  set monitorIndicatorV to [335, 223, 111, 109, 111, 109]
  MessagePut("set indicator, mon = " & monitor)
  set the castNum of sprite givMONITORDIALSPRITE to 172 + monitor
  set the castNum of sprite givMONITORINDICATORSPRITE to the number of cast "base monitor indicator cast" + monitor - 1
  set the locH of sprite givMONITORINDICATORSPRITE to getAt(monitorIndicatorH, monitor)
  set the locV of sprite givMONITORINDICATORSPRITE to getAt(monitorIndicatorV, monitor)
  updateStage()
end

on GetRandomMonitor
  set R to random(3)
  if R = 1 then
    set str to "static.BMP"
  else
    if R = 2 then
      set str to "colorbar.BMP"
    else
      set str to "test.BMP"
    end if
  end if
  return str
end